Add textobjects queries (#20924)

Co-Authored-By: Max <max@zed.dev>

Release Notes:

- vim: Added motions `[[`, `[]`, `]]`, `][` for navigating by section,
`[m`, `]m`, `[M`, `]M` for navigating by method, and `[*`, `]*`, `[/`,
`]/` for comments. These currently only work for languages built in to
Zed, as they are powered by new tree-sitter queries.
- vim: Added new text objects: `ic`, `ac` for inside/around classes,
`if`,`af` for functions/methods, and `g c` for comments. These currently
only work for languages built in to Zed, as they are powered by new
tree-sitter queries.

---------

Co-authored-by: Max <max@zed.dev>

crates/languages/src/rust/outline.scm

@@ -15,11 +15,7 @@
     (visibility_modifier)? @context
     name: (_) @name) @item
 
-(impl_item
-    "impl" @context
-    trait: (_)? @name
-    "for"? @context
-    type: (_) @name
+(function_item
     body: (_ "{" @open (_)* "}" @close)) @item
 
 (trait_item

crates/languages/src/rust/textobjects.scm

@@ -0,0 +1,51 @@
+; functions
+(function_signature_item) @function.around
+
+(function_item
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}" )) @function.around
+
+; classes
+(struct_item
+    body: (_
+        ["{" "("]?
+        [(_) ","?]* @class.inside
+        ["}" ")"]? )) @class.around
+
+(enum_item
+   body: (_
+       "{"
+       [(_) ","?]* @class.inside
+       "}" )) @class.around
+
+(union_item
+    body: (_
+        "{"
+        [(_) ","?]* @class.inside
+        "}" )) @class.around
+
+(trait_item
+    body: (_
+        "{"
+        [(_) ","?]* @class.inside
+        "}" )) @class.around
+
+(impl_item
+    body: (_
+        "{"
+        [(_) ","?]* @class.inside
+        "}" )) @class.around
+
+(mod_item
+    body: (_
+        "{"
+        [(_) ","?]* @class.inside
+        "}" )) @class.around
+
+; comments
+
+(line_comment)+ @comment.around
+
+(block_comment) @comment.around