Add textobjects queries (#20924)

Co-Authored-By: Max <max@zed.dev>

Release Notes:

- vim: Added motions `[[`, `[]`, `]]`, `][` for navigating by section,
`[m`, `]m`, `[M`, `]M` for navigating by method, and `[*`, `]*`, `[/`,
`]/` for comments. These currently only work for languages built in to
Zed, as they are powered by new tree-sitter queries.
- vim: Added new text objects: `ic`, `ac` for inside/around classes,
`if`,`af` for functions/methods, and `g c` for comments. These currently
only work for languages built in to Zed, as they are powered by new
tree-sitter queries.

---------

Co-authored-by: Max <max@zed.dev>

crates/languages/src/tsx/textobjects.scm

@@ -0,0 +1,79 @@
+(comment)+ @comment.around
+
+(function_declaration
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(method_definition
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(function_expression
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(arrow_function
+    body: (statement_block
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(arrow_function) @function.around
+(function_signature) @function.around
+
+(generator_function
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(generator_function_declaration
+    body: (_
+        "{"
+        (_)* @function.inside
+        "}")) @function.around
+
+(class_declaration
+    body: (_
+        "{"
+        [(_) ";"?]* @class.inside
+        "}" )) @class.around
+
+(class
+    body: (_
+        "{"
+        (_)* @class.inside
+        "}" )) @class.around
+
+(interface_declaration
+    body: (_
+        "{"
+        [(_) ";"?]* @class.inside
+        "}" )) @class.around
+
+(enum_declaration
+    body: (_
+        "{"
+        [(_) ","?]* @class.inside
+        "}" )) @class.around
+
+(ambient_declaration
+    (module
+    body: (_
+        "{"
+        [(_) ";"?]* @class.inside
+        "}" ))) @class.around
+
+(internal_module
+    body: (_
+        "{"
+        [(_) ";"?]* @class.inside
+        "}" )) @class.around
+
+(type_alias_declaration) @class.around