01ec6e0f77
This adds a "workspace-hack" crate, see [mozilla's](https://hg.mozilla.org/mozilla-central/file/3a265fdc9f33e5946f0ca0a04af73acd7e6d1a39/build/workspace-hack/Cargo.toml#l7) for a concise explanation of why this is useful. For us in practice this means that if I were to run all the tests (`cargo nextest r --workspace`) and then `cargo r`, all the deps from the previous cargo command will be reused. Before this PR it would rebuild many deps due to resolving different sets of features for them. For me this frequently caused long rebuilds when things "should" already be cached. To avoid manually maintaining our workspace-hack crate, we will use [cargo hakari](https://docs.rs/cargo-hakari) to update the build files when there's a necessary change. I've added a step to CI that checks whether the workspace-hack crate is up to date, and instructs you to re-run `script/update-workspace-hack` when it fails. Finally, to make sure that people can still depend on crates in our workspace without pulling in all the workspace deps, we use a `[patch]` section following [hakari's instructions](https://docs.rs/cargo-hakari/0.9.36/cargo_hakari/patch_directive/index.html) One possible followup task would be making guppy use our `rust-toolchain.toml` instead of having to duplicate that list in its config, I opened an issue for that upstream: guppy-rs/guppy#481. TODO: - [x] Fix the extension test failure - [x] Ensure the dev dependencies aren't being unified by Hakari into the main dependencies - [x] Ensure that the remote-server binary continues to not depend on LibSSL Release Notes: - N/A --------- Co-authored-by: Mikayla <mikayla@zed.dev> Co-authored-by: Mikayla Maki <mikayla.c.maki@gmail.com>
55 lines
1.4 KiB
Nix
55 lines
1.4 KiB
Nix
{
|
||
mkShell,
|
||
makeFontsConf,
|
||
|
||
zed-editor,
|
||
|
||
rust-analyzer,
|
||
cargo-nextest,
|
||
cargo-hakari,
|
||
cargo-machete,
|
||
nixfmt-rfc-style,
|
||
protobuf,
|
||
nodejs_22,
|
||
}:
|
||
(mkShell.override { inherit (zed-editor) stdenv; }) {
|
||
inputsFrom = [ zed-editor ];
|
||
packages = [
|
||
rust-analyzer
|
||
cargo-nextest
|
||
cargo-hakari
|
||
cargo-machete
|
||
nixfmt-rfc-style
|
||
# TODO: package protobuf-language-server for editing zed.proto
|
||
# TODO: add other tools used in our scripts
|
||
|
||
# `build.nix` adds this to the `zed-editor` wrapper (see `postFixup`)
|
||
# we'll just put it on `$PATH`:
|
||
nodejs_22
|
||
];
|
||
|
||
env =
|
||
let
|
||
baseEnvs =
|
||
(zed-editor.overrideAttrs (attrs: {
|
||
passthru = { inherit (attrs) env; };
|
||
})).env; # exfil `env`; it's not in drvAttrs
|
||
in
|
||
(removeAttrs baseEnvs [
|
||
"LK_CUSTOM_WEBRTC" # download the staticlib during the build as usual
|
||
"ZED_UPDATE_EXPLANATION" # allow auto-updates
|
||
"CARGO_PROFILE" # let you specify the profile
|
||
"TARGET_DIR"
|
||
])
|
||
// {
|
||
# note: different than `$FONTCONFIG_FILE` in `build.nix` – this refers to relative paths
|
||
# outside the nix store instead of to `$src`
|
||
FONTCONFIG_FILE = makeFontsConf {
|
||
fontDirectories = [
|
||
"./assets/fonts/plex-mono"
|
||
"./assets/fonts/plex-sans"
|
||
];
|
||
};
|
||
PROTOC = "${protobuf}/bin/protoc";
|
||
};
|
||
}
|