4110928314
- bump our livekit version to include a fix for a crane bug (TODO: add link when an issue is filed on crane) - switch to a clang stdenv for both linux and macos - manually unify versions of our notify crate - remove old linker flags which were only needed for livekit - fix an issue where RUSTFLAGS shadowed the rustflags from cargo configs Release Notes: - N/A
51 lines
1.3 KiB
Nix
51 lines
1.3 KiB
Nix
{
|
||
mkShell,
|
||
makeFontsConf,
|
||
|
||
zed-editor,
|
||
|
||
rust-analyzer,
|
||
cargo-nextest,
|
||
nixfmt-rfc-style,
|
||
protobuf,
|
||
nodejs_22,
|
||
}:
|
||
(mkShell.override { inherit (zed-editor) stdenv; }) {
|
||
inputsFrom = [ zed-editor ];
|
||
packages = [
|
||
rust-analyzer
|
||
cargo-nextest
|
||
nixfmt-rfc-style
|
||
# TODO: package protobuf-language-server for editing zed.proto
|
||
# TODO: add other tools used in our scripts
|
||
|
||
# `build.nix` adds this to the `zed-editor` wrapper (see `postFixup`)
|
||
# we'll just put it on `$PATH`:
|
||
nodejs_22
|
||
];
|
||
|
||
env =
|
||
let
|
||
baseEnvs =
|
||
(zed-editor.overrideAttrs (attrs: {
|
||
passthru = { inherit (attrs) env; };
|
||
})).env; # exfil `env`; it's not in drvAttrs
|
||
in
|
||
(removeAttrs baseEnvs [
|
||
"LK_CUSTOM_WEBRTC" # download the staticlib during the build as usual
|
||
"ZED_UPDATE_EXPLANATION" # allow auto-updates
|
||
"CARGO_PROFILE" # let you specify the profile
|
||
"TARGET_DIR"
|
||
])
|
||
// {
|
||
# note: different than `$FONTCONFIG_FILE` in `build.nix` – this refers to relative paths
|
||
# outside the nix store instead of to `$src`
|
||
FONTCONFIG_FILE = makeFontsConf {
|
||
fontDirectories = [
|
||
"./assets/fonts/plex-mono"
|
||
"./assets/fonts/plex-sans"
|
||
];
|
||
};
|
||
PROTOC = "${protobuf}/bin/protoc";
|
||
};
|
||
}
|