400e938997
This PR extracts Ruby and ERB support into an extension and removes the built-in Ruby and Ruby support from Zed. As part of this, the new extension is prepared for adding support for the `Ruby LSP` which has some blockers. See https://github.com/zed-industries/zed/pull/8613 I was thinking of adding an initial support for Ruby LSP but I think it would be better to start with extracting the Ruby extension for now. The implementation, as the 1st step, matches the bundled version but with 3 differences: 1. Added signature output to the completion popup. See my comment below.  3. Use the shell environment for starting the `solargraph` executable. See my comment below. 4. Bumped the tree sitter version for Ruby to the latest available version. Additionally, I plan to tweak this extension a bit in the future but I think we should do this bit by bit. Thanks! Release Notes: - Removed built-in support for Ruby, in favor of making it available as an extension. --------- Co-authored-by: Marshall Bowers <elliott.codes@gmail.com>
202 lines
2.5 KiB
Scheme
202 lines
2.5 KiB
Scheme
; Keywords
|
|
|
|
[
|
|
"alias"
|
|
"and"
|
|
"begin"
|
|
"break"
|
|
"case"
|
|
"class"
|
|
"def"
|
|
"do"
|
|
"else"
|
|
"elsif"
|
|
"end"
|
|
"ensure"
|
|
"for"
|
|
"if"
|
|
"in"
|
|
"module"
|
|
"next"
|
|
"or"
|
|
"rescue"
|
|
"retry"
|
|
"return"
|
|
"then"
|
|
"unless"
|
|
"until"
|
|
"when"
|
|
"while"
|
|
"yield"
|
|
] @keyword
|
|
|
|
((identifier) @keyword
|
|
(#match? @keyword "^(private|protected|public)$"))
|
|
|
|
; Function calls
|
|
|
|
((identifier) @function.method.builtin
|
|
(#eq? @function.method.builtin "require"))
|
|
|
|
"defined?" @function.method.builtin
|
|
|
|
(call
|
|
method: [(identifier) (constant)] @function.method)
|
|
|
|
; Function definitions
|
|
|
|
(alias (identifier) @function.method)
|
|
(setter (identifier) @function.method)
|
|
(method name: [(identifier) (constant)] @function.method)
|
|
(singleton_method name: [(identifier) (constant)] @function.method)
|
|
(method_parameters [
|
|
(identifier) @variable.parameter
|
|
(optional_parameter name: (identifier) @variable.parameter)
|
|
(keyword_parameter [name: (identifier) (":")] @variable.parameter)
|
|
])
|
|
|
|
(block_parameters (identifier) @variable.parameter)
|
|
|
|
; Identifiers
|
|
|
|
((identifier) @constant.builtin
|
|
(#match? @constant.builtin "^__(FILE|LINE|ENCODING)__$"))
|
|
|
|
(file) @constant.builtin
|
|
(line) @constant.builtin
|
|
(encoding) @constant.builtin
|
|
|
|
(hash_splat_nil
|
|
"**" @operator
|
|
) @constant.builtin
|
|
|
|
(global_variable) @constant
|
|
|
|
(constant) @type
|
|
|
|
((constant) @constant
|
|
(#match? @constant "^[A-Z\\d_]+$"))
|
|
|
|
(superclass
|
|
(constant) @type.super)
|
|
|
|
(superclass
|
|
(scope_resolution
|
|
(constant) @type.super))
|
|
|
|
(superclass
|
|
(scope_resolution
|
|
(scope_resolution
|
|
(constant) @type.super)))
|
|
|
|
(self) @variable.special
|
|
(super) @variable.special
|
|
|
|
[
|
|
(class_variable)
|
|
(instance_variable)
|
|
] @variable.member
|
|
|
|
|
|
; Literals
|
|
|
|
[
|
|
(string)
|
|
(bare_string)
|
|
(subshell)
|
|
(heredoc_body)
|
|
(heredoc_beginning)
|
|
] @string
|
|
|
|
[
|
|
(simple_symbol)
|
|
(delimited_symbol)
|
|
(hash_key_symbol)
|
|
(bare_symbol)
|
|
] @string.special.symbol
|
|
|
|
(regex) @string.regex
|
|
(escape_sequence) @escape
|
|
|
|
[
|
|
(integer)
|
|
(float)
|
|
] @number
|
|
|
|
[
|
|
(nil)
|
|
(true)
|
|
(false)
|
|
] @constant.builtin
|
|
|
|
(comment) @comment
|
|
|
|
; Operators
|
|
|
|
[
|
|
"!"
|
|
"~"
|
|
"+"
|
|
"-"
|
|
"**"
|
|
"*"
|
|
"/"
|
|
"%"
|
|
"<<"
|
|
">>"
|
|
"&"
|
|
"|"
|
|
"^"
|
|
">"
|
|
"<"
|
|
"<="
|
|
">="
|
|
"=="
|
|
"!="
|
|
"=~"
|
|
"!~"
|
|
"<=>"
|
|
"||"
|
|
"&&"
|
|
".."
|
|
"..."
|
|
"="
|
|
"**="
|
|
"*="
|
|
"/="
|
|
"%="
|
|
"+="
|
|
"-="
|
|
"<<="
|
|
">>="
|
|
"&&="
|
|
"&="
|
|
"||="
|
|
"|="
|
|
"^="
|
|
"=>"
|
|
"->"
|
|
(operator)
|
|
] @operator
|
|
|
|
[
|
|
","
|
|
";"
|
|
"."
|
|
"::"
|
|
] @punctuation.delimiter
|
|
|
|
[
|
|
"("
|
|
")"
|
|
"["
|
|
"]"
|
|
"{"
|
|
"}"
|
|
"%w("
|
|
"%i("
|
|
] @punctuation.bracket
|
|
|
|
(interpolation
|
|
"#{" @punctuation.special
|
|
"}" @punctuation.special) @embedded
|